;Flags, Variables and Counter, Etc.
;
;Flag 0  Display CMD detail as it is being processed
         enter DEBUG to toggle ON and OFF
;Flag 1  When on Jose is present but has not been paid
;Flag 2  On when Noun 215 (Bull) is read.
;Flag 3  On when Noun 217 (Man) is read
;Flag 4  On when Noun 219 (Eagle) is read
;Flag 5  On when Noun 221 (Lion) is read
;Flag 6  On when Guardian has been present 1st time in inst. chamber.
;Flag 7  On once welcome speech by guardian has been given
;Flag 8  On once meaning of circle & square has been given--msg 28
;Flag 9  On - player has sat in stone chair in instruction chamber
;Flag 10 On once Rough Place (214) is open (at 23)
;Flag 11 On once Rough Spot (216) is open (at 24)
;Flag 12 On once Irregular Spot (220) is open (at 25)
;Flag 13 On once Irregular Place (218) is open (at 26)
;Flag 14 On indicates first visit to Turbulare is complete
;Flag 15 On: the gem is not on the pedestal
;Flag 16 on: the gem has been removed from pedestal, may be back
;Flag 17 On: player has met lion involving gem
;Flag 18 On: Player has put gem on pedestal at least once
;Flag 19 On: Player has heard the orientation speech (MSG 24)
;Flag 20 On: Player is standing on the platform
;Flag 21 On: Stone box is open
;Flag 22 On: Reminder about the box lid being open has been given
;Flag 23 On: Old man is somewhere
;Flag 24 On: Player has talked to Lion
;Flag 25 On: Player has been forced to go to Emerald Chamber
;Flag 26 On: Lion has been left behind during vial/Turbulare sequence
;Flag 27 On: First time player sees Aquarius
;Flag 28 On: Player has talked to Aquarius
;Flag 29 On: Aquarius has sent player to north side of pyramid
;Flag 30 On: Player has taken white crystal sphere (238)
;Flag 31 On: Correctly answered Aquarius' question
;Flag 32 On: Kinkajou has sandwich and run away (both destroyed)
;Flag 33 On: 
;Flag 34 On: Player has correctly answered Scorpio's question
;Flag 35 On: Turned on when enter yellow door: turned off if attack eagle
;              or entered sea
;Flag 36 On: Player has talked to eagle at least once
;Flag 37 On: Player has taken yellow sphere from grotto
;Flag 38 On: Entered Mu through red door/not attacked bull/not entered cave
;Flag 39 On: Has correctly answered Taurus' question
;Flag 40 On: When player 1st removes crystal
;Flag 41 On: First time to meadow each new time in Mu
;Flag 42 On: Player has spoken to bull
;Flag 43 On: 1st move player sent out of Mu: checks status of circle
;Flag 44 On: 1st move player sent out of Mu: checks status of square
;Flag 45 On: 1st move player sent out of Mu: checks status of flashlight

;Counter 1  Counts from pyramid until Jose is paid
;           Counts from entering bus until driver is paid
;Counter 2  Gem removed from pedestal until lion appears or gem returned
;Counter 3  Lion appears until either lion or player talks to the other
;Counter 4  Lions message until gem returned or player killed
;Counter 5  Counts moves until player returns gem or Game End
;Counter 6  Counts moves until Old Man Dissappears

; JumpTo Commands -- used for programmer to get around.

Command JumpTo44
IsCarrying 201  - Flashlight
IsCarrying 202  - Stone Star
GoToRoom 44  - Half Sphere Chamber
DoneWithTurn
END_Command

;Any Commands

Command Any
AtLocation 3  - Hotel Lobby
 Or
AtLocation 7  - Bus Stop
 Or
AtLocation 10  - Bus to Muna
 Or
AtLocation 11  - Under way to Muna
PutInCurrentRoom 212  - Next Bus
END_Command

; Bus Driver related

Command Any
AtLocation 10  - Bus to Muna
 Or
AtLocation 11  - Under way to Muna
PutInCurrentRoom 213  - Bus Driver
END_Command

Command Any
AtLocation 10   - Bus to Muna
CounterLT 1 1   - counter 1 is for # of turns to pay bus driver
TurnCounterON 1
END_Command

Command Any
AtLocation 10
CounterGT 1 6  - six turns before driver gets impatient
PrintMessage 10 - Too long-kicked off bus-bus leaves.
TurnCounterOff 1
GoToRoom 4 - Empty Street in front of Hotel.
DoneWithTurn
END_Command

;;Pay Jose Related Any Commands

Command Any
VerbIsDirection
FlagON 1  -  Jose has not been paid
AtLocationGT 22
AtLocationLT 27
PrintMessage 3  - Jose has followed you and wants to be paid
END_Command

Command Any
CounterGT 1 15
TurnCounterOFF 1  -  No longer counting turns until Jose paid
PrintMessage 16  - You didn't pay Jose so he killed you
MinusScore 10
SendToRoom 305 0  - Destroy Jose
SendToRoom 207 0  - American Currency
SendToRoom 200 0  - Destroy Wallet
SendToRoom 203 2  - Coins to Hotel Room
TurnFlagOff 1  - Jose has been paid or has killed player
TurnFlagON 51  - Player killed by Jose
KillPlayer  - must pay Jose within 10 turns or player is killed
DoneWithTurn
END_Command

Command Any
NewLife
FlagOn 51  - Player has been killed by Jose
PrintMessage 121  - Wallet is missing and score is reduced
TurnFlagOFF 51  - Flag reset
END_Command

;Makes door in pyramid appear

Command Any
AtLocation 25
FlagOff 1  -  Jose has been paid
PutInCurrentRoom 223  - Make visible Pyramid Door
PutInCurrentRoom 224  - Make visible Star-shapped Recess
END_Command

;;Any; Lion joins player

Command Any
CounterGT 2 25  - Gem absent from pedestal 26 turns
Not AtLocationGT 44  - Not in room greater than 44
AtLocationGT 29  - Player is in the pyramid (except ent chmbr w/ door open)
TurnCounterOFF 2  - Lion appears--hostile 308
PutInCurrentRoom 308  - Lion appears--hostile
TurnCounterON 3  - Until player or lion talks to the other
PrintMessage 44  - Suddenly you notice a large fierce looking Lion
DoneWithTurn
END_Command

Command Any
AtLocationGT 29
AtLocationLT 45
CounterGT 3 10  - Hostile lion & player together 11 turns
PrintMessage 38  - Lion tells player to return the gem
END_Command

Command Any
AtLocationGT 29
AtLocationLT 45
CounterGT 3 10  - Hostile lion & player together 11 turns
FlagOff 7  - Player has not heard guardian's introduction
PrintMessage 39  - Return to stone chair for pyramid orientation
PrintMessage 48  - You may leave room--should return gem
TurnCounterOFF 3  - Lion has talked to player
Destroy 308  - Hostile Lion
PutInCurrentRoom 309  - Freindly lion
TurnCounterON 4  - Lions message until gem returned or player killed
TurnFlagON 17  - Player has met lion
DoneWithTurn
END_Command

Command Any
AtLocationGT 29
AtLocationLT 45
CounterGT 3 10  - Hostile lion & player together 11 turns
PrintMessage 48  - You may leave but should return gem
TurnCounterOFF 3  - Lion has talked to player
Destroy 308  - Hostile Lion
PutInCurrentRoom 309  - Freindly lion
TurnCounterON 4  - Lions message until gem returned or player killed
TurnFlagON 17  - Player has met lion
DoneWithTurn
END_Command

Command Any
CounterGT 4 15  - Player has not returned Gem in 16 turns
AtLocationGT 29  - Ground level of pyramid
AtLocationLT 45  - Ground level of pyramid
FlagON 20  - Player is on the platform
ToggleFlag 20  - Takes player off the platform
END_Command

Command Any
CounterGT 4 15  - Player has not returned Gem in 16 turns
AtLocationGT 29  - Ground level of pyramid
AtLocationLT 45  - Ground level of pyramid
PrintMessage 41  - Sent to gem chamber
SendToRoom 311 39  - Guardian to gem chamber
SendToRoom 308 39  - Hostile lion to gem chamber
Destroy 309  - Freindly lion to 0
SendToRoom 233 39 - Gem to gem chamber
END_Command

Command Any
CounterGT 4 15  - Player has not returned Gem in 16 turns
AtLocationGT 29  - Ground level of pyramid
AtLocationLT 45  - Ground level of pyramid
TurnCounterOn 5  -  now counting until end game
TurnFlagOn 19  - Player sent to gem chamber w/ guardian and lion
MinusScore 10
TurnCounterOff 4  - Player has been sent to gem chamber
GoToRoom 39  - Gem chamber
LookAtRoom
DoneWithTurn
END_Command

Command Any
CounterEquals 5 8  - Player has had 8 turns to put gem on pedestal
PrintMessage 47  - Put gem on Pedestal
END_Command

Command Any
CounterGT 5 9  - Player has had more than 9 turns to put gem on pedestal
CounterLT 5 12  - Not more than 11 chances
PrintMessage 47  - Put gem on Pedestal
END_Command

Command Any
CounterGT 5 11  -  Had 11 chances to return gem
PrintMessage 46  - End game message
EndGame
DoneWithTurn
END_Command

;;Related to Stone Box

Command Any
VerbIsDirection
Not IsLocated 230 229  - Stone circle is not in the stone box
Not IsLocated 231 229  - Stone square is not in the stone box
FlagOn 21  - Box is open
FlagOff 22  - Player not told the box is open
PrintMessage 56  - You remember that you left the box open.
TurnFlagOn 22  - Player told the box is open
END_Command

;;Relating to elevating column

Command Any
VerbIsDirection
FlagOn 20  - Player is on the platform
ToggleFlag 20  - Player is not on platform
END_Command

;;Flashlight, star & Kinkajou--from Ra

Command Any
AtLocation 63
FlagOn 33  - Answered question wrong
FlagOff 29  - Kinkajou has not appeared before
NOT IsCarrying 201  - Is not carrying the flashlight
SendToRoom 201 25  - Flashlight to east side of pyramid
SendToRoom 313 25  - Kinkajou to east side of pyramid
TurnFlagOn 29  - Kinkajou has appeared
END_Command

Command Any
AtLocation 63
FlagOn 33  - Answered question wrong
FlagOff 29  - Kinkajou has not appeared before
NOT IsCarrying 202  - Star
SendToRoom 202 25  - star to east side of pyramid
SendToRoom 313 25  - Kinkajou to east side of pyramid
TurnFlagOn 29  - Kinkajou has appeared
END_Command

Command Any
AtLocation 63
FlagOn 33  - Answered question wrong
FlagOff 29  - Kinkajou has not appeared before
NOT IsCarrying 231  - Stone Square
SendToRoom 231 25  - Square to east side of pyramid
SendToRoom 313 25  - Kinkajou to east side of pyramid
TurnFlagOn 29  - Kinkajou has appeared
END_Command

Command Any
AtLocation 63
FlagOn 33  - Answered question wrong
FlagOn 29  - Kinkajou has appeared
NOT IsCarrying 201  - Is not carrying flashlight
SendToRoom 201 25  - Flashlight to east side of pyramid
END_Command

Command Any
AtLocation 63
FlagOn 33  - Answered question wrong
FlagOn 29  - Kinkajou has appeared
NOT IsCarrying 202  - Is not carrying Star
SendToRoom 202 25  - Star to east side of pyramid
END_Command

Command Any
AtLocation 63
FlagOn 33  - Answered question wrong
FlagOn 29  - Kinkajou has appeared
NOT IsCarrying 231  - Is not carrying Stone Square
SendToRoom 231 25  - Square to east side of pyramid
END_Command

Command Any
AtLocation 63
FlagOn 33  - Answered question wrong
TurnFlagOff 33  - Reset 33-player can go back to 63
PrintMessage 77  - Vision blurs and returns
GoToRoom 24  - North side of pyramid
LookAtRoom
DoneWithTurn
END_Command

;;Kinkajou

Command Any
AtLocation 25  - East Side of Pyramid
Present 313  - Kinkajou
Present 201  - flashlight
 OR
Present 202  - Stone Star
 OR
Present 231  - Stone Square
PrintMessage 73  - Kinkajou plays with the flashligh
END_Command

;;Flashlight, star & Kinkajou--from Ta

Command Any
AtLocation 123  - Golden Disk
FlagOn 50  - Answered question wrong
FlagOff 29  - Kinkajou has not appeared before
NOT IsCarrying 201  - Is not carrying the flashlight
SendToRoom 201 25  - Flashlight to east side of pyramid
SendToRoom 313 25  - Kinkajou to east side of pyramid
TurnFlagON 29  - Kinkajou has appeared
END_Command

Command Any
AtLocation 123  - Golden Disk
FlagOn 50  - Answered question wrong
FlagOff 29  - Kinkajou has not appeared before
NOT IsCarrying 202  - Star
SendToRoom 202 25  - Star to east side of pyramid
SendToRoom 313 25  - Kinkajou to east side of pyramid
TurnFlagON 29  - Kinkajou has appeared
END_Command

Command Any
AtLocation 123  - Golden Disk
FlagOn 50  - Answered question wrong
FlagOff 29  - Kinkajou has not appeared before
NOT IsCarrying 231  - Stone Square
SendToRoom 231 25  - Stone square to east side of pyramid
SendToRoom 313 25  - Kinkajou to east side of pyramid
TurnFlagON 29  - Kinkajou has appeared
END_Command

Command Any
AtLocation 123  - Golden Disk
FlagOn 50  - Answered question wrong
FlagOn 29  - Kinkajou has already appeared
NOT IsCarrying 201  - Is not carrying the flashlight
SendToRoom 201 25  - Flashlight to east side of pyramid
END_Command

Command Any
AtLocation 123  - Golden Disk
FlagOn 50  - Answered question wrong
FlagOn 29  - Kinkajou has already appeared
NOT IsCarrying 202  - Star
SendToRoom 202 25  - Star to east side of pyramid
END_Command

Command Any
AtLocation 123  - Golden Disk
FlagOn 50  - Answered question wrong
FlagOn 29  - Kinkajou has already appeared
NOT IsCarrying 231  - Stone Square
SendToRoom 231 25  - Stone square to east side of pyramid
END_Command

Command Any
AtLocation 123  - Golden Disk
FlagOn 50  - Answered question wrong
TurnFlagOFF 50  - Reset 50--player may rerun sequence
PrintMessage 77  - Vison blurs and returns
GoToRoom 26  - South side of pyramid
DoneWithTurn
END_Command

;;Corrects status of circle, square, & flashlight--Mu sequence

Command Any
FlagOn 43  - Player sent out of Mu (circle)
NOT Present 230  - Stone circle
NOT IsLocated 230 47  - circle not in lower level central chamber
NOT IsCarrying 230  - Stone circle
SendToRoom 230 47  - Stone circle to lower level central chamber
TurnFlagOff 43  - Circle's status corrected
END_Command

Command Any
FlagOn 43  - Player sent out of Mu (circle)
TurnFlagOff 43  - Circle's status corrected
END_Command

Command Any
FlagOn 44  - Player sent out of Mu (square)
NOT Present 231  - Stone square
NOT IsLocated 231 47  - square not in lower level central chamber
NOT IsCarrying 231  - Stone square 
SendToRoom 231 47  - Stone square to lower level central chamber
TurnFlagOff 44  - Square's status corrected
END_Command

Command Any
FlagOn 44  - Player sent out of Mu (square)
TurnFlagOff 44  - Square's status corrected
END_Command

Command Any
FlagOn 45  - Player sent out of Mu (flashlight)
NOT Present 201  - Flashlight
NOT IsCarrying 201  - Flashlight
SendToRoom 201 49  - Flashlight to Standing By West Door (closed)
TurnFlagOff 45  - Flashlight's status corrected
END_Command

Command Any
FlagOn 45  - Player sent out of Mu (flashlight)
TurnFlagOff 45  - Flashlight's status corrected
END_Command

; Ask Commands

;;Ask Jose

Command Ask Chicelero
ReDirectTo Talk to Chicelero
END_Command

;;Ask Driver

Command Ask Driver
ReDirectTo Talk to Driver
END_Command

; Direction Commands

;;Relates to Pay Jose

Command East
AtLocation 21  - Moving to West side of pyramid
Present 305  - Jose
FlagOFF 1 -  When on Jose not yet paid
PrintMessage 2  - Jose-here we are, I want paid
TurnFlagOn 1  -  Goes off when Jose gets paid
TurnCounterOn 1  -  counter gives 10 turns to pay Jose
END_Command

;;Relates to movement of moss on pyramid walls

Command East
AtLocation 22  - Rainforest Trail
FlagOff 10  - 214 unopened
SendToRoom 222 23  - Moss to West Side
END_Command

Command Southeast
AtLocation 24  - North Side
FlagOff 12  - 220 unopened
SendToRoom 222 25  - Moss to East side
END_Command

Command Southeast
AtLocation 23  - West Side
FlagOff 13  - 218 unopened
SendToRoom 222 26  - Moss to South side
END_Command

Command Southwest
AtLocation 25  - East side
FlagOff 13  - 218 unopened
SendToRoom 222 26  - Moss to South side
END_Command

Command Southwest
AtLocation 24  - North side
FlagOff 10  - 214 unopened
SendToRoom 222 23  - Moss to West side
END_Command

Command Northeast
AtLocation 23  - West Side
FlagOff 11  - 216 unopened
SendToRoom 222 24  - Moss to North side
END_Command

Command Northeast
AtLocation 26  - south side of pyramid
FlagOff 12  - 220 unopened
SendToRoom 222 25  - Moss to east side
END_Command

Command Northwest
AtLocation 26  - south side
FlagOff 10  - 214 unopened
SendToRoom 222 23  - Moss to West side 
END_Command

Command Northwest
AtLocation 25  - east side
FlagOff 11  - 216 unopened
SendToRoom 222 24  - Moss to North side
END_Command

;;Relates to operation of pyramid door

Command Southeast
AtLocation 24  - North Side of Pyramid
FlagOff 1  -  Jose has been paid (or has not asked for payment)
SendToRoom 224 25  - Put recess on east side of pyramid
SendToRoom 223 25  - Put door on east side of pyramid
END_Command

Command Northeast
AtLocation 26  - South Side of Pyramid
FlagOff 1  -  Jose has been paid (or has not asked for payment)
SendToRoom 224 25  - Put recess on east side of pyramid
SendToRoom 223 25  - Put door on east side of pyramid
END_Command

Command West
AtLocation 28  - East side open door
SendToRoom 224 29  - Put recess in entrance chamber w/ open door
END_Command

Command Enter
AtLocation 28  - East side open door
SendToRoom 224 29  - Put recess in entrance chamber w/ open door
END_Command

Command Enter Pyramid
AtLocation 28
SendToRoom 224 29  - Put recess in entrance chamber w/ open door
GoToRoom 29  - Entrance Chamber (door open)
DoneWithTurn
END_Command

Command East
AtLocation 29  - Entrance chamber w/ open door
SendToRoom 224 28  - Put recess in east side with open door
END_Command

Command East
AtLocation 31   - Short East-West Passage
SendToRoom 224 30  -  Put recess in entrance chamber with closed door
SendToRoom 223 30  -  Put door in entrance chamber with closed door
END_Command

;;Message that player sees kinkajou playing with items he left inside

Command SouthEast
AtLocation 24  - North side of pyramid
IsLocated 313 25  - Kinkajou at east side, pyramid door
PrintMessage 74  - Player sees kinkajou playing with items he needs
END_Command

Command NorthEast
AtLocation 26  - South side of pyramid
IsLocated 313 25  - Kinkajou at east side, pyramid door
PrintMessage 74  - Player sees kinkajou playing with items he needs
END_Command

;;East relating to door closing with gem

Command East
AtLocation 29  - Entrance chamber w/ open door
IsCarrying 233  - Large Gem
PrintMessage 42  - Door closes on player
TimePasses
PrintMessage 45  - Regain consciousness & Guardian tells to replace gem
SendToRoom 311 39  - Guardian to gem chamber
SendToRoom 308 39  - Hostile lion to gem chamber
Destroy 309  - Freindly Lion
END_Command

Command East
AtLocation 29  - Entrance chamber w/ open door
IsCarrying 233  - Large Gem
SendToRoom 233 39  - Gem to Gem Chamber
TurnCounterON 5
TurnFlagOn 19  - Sent to gem chamber with guardian & Lion
TurnCounterOFF 4  -  Superceded by counter 5 if it was on
TurnCounterOFF 3  -  Superceded by counter 5 if it was on
GoToRoom 39
MinusScore 10
LookAtRoom
DoneWithTurn
END_Command

;;Exit relating to door closing with gem

Command Exit
AtLocation 29  - Entrance chamber w/ open door
IsCarrying 233  - Large Gem
PrintMessage 42  - Door closes on player
TimePasses
PrintMessage 45  - Regain consciousness & Guardian tells to replace gem
SendToRoom 311 39  - Guardian to gem chamber
SendToRoom 308 39  - Hostile lion to gem chamber
Destroy 309  - Freindly Lion
END_Command

Command Exit
AtLocation 29  - Entrance chamber w/ open door
IsCarrying 233  - Large Gem
SendToRoom 233 39  - Gem to Gem Chamber
TurnCounterON 5
TurnFlagOn 19  - Sent to gem chamber with guardian & Lion
TurnCounterOFF 4  -  Superceded by counter 5 if it was on
TurnCounterOFF 3  -  Superceded by counter 5 if it was on
GoToRoom 39
MinusScore 10
LookAtRoom
DoneWithTurn
END_Command

;;Bus stop related

Command Enter Hotel
AtLocation 7  - Bus stop w/ bus present
GoToRoom 3  - Hotel lobby
DoneWithTurn
END_Command

Command Enter Lobby
AtLocation 7  - Bus stop w/ bus present
GoToRoom 3  - Hotel lobby
DoneWithTurn
END_Command

;;Bus Driver Related
 
Command Exit
AtLocation 10  - Bus to Muna
TurnCounterOff 1  - reset # of turns to pay driver
END_Command

;;Entering instruction chamber

Command West
AtLocation 31
FlagOff 6  - First time in Instruction Chamber
SendToRoom 306 37   - Pyramid Guardian to Instruction Chamber
TurnFlagOn 6  - Guardian has appeared in Instruction Chamber
END_Command

;;Places Narrow Band of Carvings in Short Passages

Command South
AtLocation 39 - Large Gem Chamber
SendToRoom 226 32
END_Command

Command South
AtLocation 44  - Half Sphere Chamber
SendToRoom 226 42
END_Command

Command North
AtLocation 40  - Potion Vial Chamber
SendToRoom 226 42
END_Command

Command North
AtLocation 44  - Half Sphere Chamber
SendToRoom 226 32
END_Command

Command East
AtLocation 38  - Stone Box Chamber
SendToRoom 226 43
END_Command

Command East
AtLocation 44  - Half Sphere Chamber
SendToRoom 226 41
END_Command

Command West
AtLocation 37  - Instruction Chamber
SendToRoom 226 41
END_Command

Command West
AtLocation 44  - Half Sphere Chamber
SendToRoom 226 43
END_Command

;;Places elevating column

Command South
AtLocation 32  - Short North-South Passage
SendToRoom 234 44  - Circular Platform to Half Sphere Chamber
END_Command

Command South
AtLocation 60  - Entrance to the domain of Ra
SendToRoom 234 47  - Circular Platform to Lower Level Central Chamber
END_Command

Command North
AtLocation 42  - Short North-South Passage
SendToRoom 234 44  - Circular Platform to Half Sphere Chamber
END_Command

Command North
AtLocation 120  - Entrance to the domain of Ta
SendToRoom 234 47  - Circular Platform to Lower Level Central Chamber
END_Command

Command East
AtLocation 43  - Short East-West Passage
SendToRoom 234 44  - Circular Platform to Half Sphere Chamber
END_Command

Command East
AtLocation 90  - Entrance to the domain of Mu
SendToRoom 234 47  - Circular Platform to Lower Level Central Chamber
END_Command

Command West
AtLocation 41  - Short East-West Passage
SendToRoom 234 44  - Circular Platform to Half Sphere Chamber
END_Command

Command West
AtLocation 150  - Entrance to the domain of La
SendToRoom 234 47  - Circular Platform to Lower Level Central Chamber
END_Command

;;Relating to moving doors to domains: Ra

Command North
AtLocation 52  - Standing by north door
SendToRoom 237 60  - White door to entrance chamber to Ra
END_Command

Command South
AtLocation 60  - Entrance Chamber: Ra
SendToRoom 237 52  - White Door to Standing by North Door
END_Command

Command South
AtLocation 62  - Domain of Ra
SendToRoom 237 61  - White Door to Entrance Chamber: Domain of Ra
END_Command

;;Relating to moving doors to domains: Mu

Command West
AtLocation 53  - Standing by West Door (open)
SendToRoom 239 90  - Red door to Entrance Chamber: Mu (open)
TurnFlagOn 38  - Player has entered domain of Mu
END_Command

Command East
AtLocation 90  - Entrance Chamber: Mu (open)
SendToRoom 239 53  - Red Door to Standing by West door (open)
TurnFlagOff 41  - Player is leaving Mu
END_Command

Command East
AtLocation 92  - Domain of Mu
SendToRoom 239 91  - Red door to Entrance Chamber: Mu (closed)
END_Command

;;Relating to moving doors to domains: Ta

Command South
AtLocation 54  - Standing by south door (open)
SendToRoom 241 120  - Blue door to Entrance Chamber: Ta (open)
END_Command

Command North
AtLocation 120  - Entrance Chamber: Ta (open)
SendToRoom 241 54  - Blue door to Standing by south door (open)
END_Command

Command North
AtLocation 122  - Domain of Ta
SendToRoom 241 121  - Blue door to Entrance Chamber: Ta (closed)
END_Command

;;Relating to moving doors to domains: La

Command East
AtLocation 55  - Standing by East Door
SendToRoom 243 150  - Yellow door to Entrance Chamber: La (open)
TurnFlagOn 35  - Fresh start in Domain of La, resets sequence
END_Command

Command West
AtLocation 150  - Entrance Chamber: La (open)
SendToRoom 243 55  - Yellow door to Standing by east door
END_Command

Command West
AtLocation 152  - Domain of La
SendToRoom 243 151  - Yellow door to Entrance Chamber: La (closed)
END_Command

;;Domain of Ra

Command North
AtLocation 60  - Entrance: Domain of Ra
FlagOff 27  - First time to Domain of Ra
PrintMessage 62  - ammazment at the Domain of Ra
TurnFlagOn 27  - Have been to domain of Ra
END_Command

Command North
AtLocation 62
IsLocated 238 63  - White sphere is at Presence of Aquarius
GoToRoom 63  - Presence of Aquarius
LookAtRoom
PrintMessage 75  - Aquarius laughs and offers white sphere to player
DoneWithTurn
END_Command

;;Domain of Mu

Command West
AtLocation 92  - Domain of Mu
FlagOn 38  - Player has entered domain & not attacked bull or gone in cave
FlagOff 39  - Have not correctly answered Taurus' question
FlagOff 40  - Have not removed crystal from stalagmite.
Flagoff 41  - Have not yet been to meadow this time in domain
PrintMessage 96  - First see bull in the meadow
SendToRoom 316 93  - Bull to grassy meadow
TurnFlagOn 41  - Player has now been in meadow this time in Mu
END_Command

Command North
AtLocation 93  - Grassy Meadow
PrintMessage 94  - Swift river blocks your way.
DoneWithTurn
END_Command

Command West
AtLocation 93  - Grassy Meadow
PrintMessage 94  - Swift river blocks your way.
DoneWithTurn
END_Command

Command Northwest
AtLocation 93  - Grassy Meadow
PrintMessage 94  - Swift river blocks your way.
DoneWithTurn
END_Command

Command West
AtLocation 92
FlagOff 38  - Player has attacked bull or been in cave
PrintMessage 98  - Enter meadow and see bull across the river
END_Command

Command North
AtLocation 94  - Open Chamber of Cave
FlagOff 38  - Player has attacked bull or been in cave
PrintMessage 98  - Enter meadow and see bull across the river
Destroy 316  - Bull
END_Command

Command South
AtLocation 93  Grassy Meadow
FlagOn 39  - Player has correctly answered Taurus' question
FlagOff 40  - Crystal has not been removed from stalagmite
PrintMessage 99  - Player enters cave
SendToRoom 240 94  - Red Sphere to Cave
GoToRoom 94  - Open Chamber of Cave
TurnFlagOff 38  - Player has entered cave
DoneWithTurn
END_Command

Command South
AtLocation 93  Grassy Meadow
PrintMessage 99  - Player enters cave
TurnFlagOff 38  - Player has entered cave
END_Command

Command Enter River
AtLocation 93  - Grassy Meadow
PrintMessage 95
DoneWithTurn
END_Command

Command Enter Cave
AtLocation 93  Grassy Meadow
FlagOn 39  - Player has correctly answered Taurus' question
FlagOff 40  - Crystal has not been removed from stalagmite
PrintMessage 99  - Player enters cave
SendToRoom 240 94  - Red Sphere to Cave
GoToRoom 94  - Cave
TurnFlagOff 38  - Player has entered cave
DoneWithTurn
END_Command

Command Enter Cave
AtLocation 93  Grassy Meadow
PrintMessage 99  - Player Enters Cave
GoToRoom 94  - Cave
TurnFlagOff 38  - Player has entered cave
DoneWithTurn
END_Command

Command Exit Cave
AtLocation 94  - Player in Cave
GoToRoom 93  - Grassy Meadow
PrintMessage 98  - Enter meadow and see Bull across the river
Destroy 316  - Bull
DoneWithTurn
END_Command

;;Domain of Ta

Command South
AtLocation 120  - Entrance Chamber: Ta
FlagOff 47  - Has not yet been on light ribbon
PrintMessage 107  -  Rush through door
TurnFlagOn 47  - No has been on light ribbon
END_Command

Command South
AtLocation 120
  OR
AtLocation 121  - Entrance Chamber: Ta
PrintMessage 108  - Look to the south
PrintMessage 109  - Walk on light ribbon
END_Command

Command South
AtLocation 122  - Intersection
PrintMessage 109  - Walk on ribbon
END_Command

Command North
AtLocation 122  - Intersection
 OR
AtLocation 124  - Columns of Light
PrintMessage 109  - Walk on ribbon
END_Command

Command East
AtLocation 122  - Intersection
PrintMessage 109  - Walk on ribbon
END_Command

Command West
AtLocation 123  - Golden disk
PrintMessage 109  - Walk on ribbon
END_Command

;;Domain of La

Command East
AtLocation 150  - Entrance Chamber: La
FlagOff 34  - Player has not yet correctly answered Scorpio's question
FlagOn 35  - Player has not attacked eagle or gone in sea this time
FlagOff 37  - Player has not yet taken the yellow sphere from the grotto
 OR
AtLocation 151  - Entrance chamber: La
FlagOff 34  - Player has not yet correctly answered Scorpio's question
FlagOn 35  - Player has not attacked eagle or gone in sea this time
FlagOff 37  - Player has not yet taken the yellow sphere from the grotto
PrintMessage 83  - Eagle flys in
SendToRoom 314 152
END_Command

Command East
AtLocation 152  - Domain of La
PrintMessage 84  - Walk into the water
TurnFlagOFF 35  - Have entered sea
Destroy 314  - Eagle
END_Command

Command East
AtLocation 152  - Domain of La
FlagOn 34  - Has correctly answered Scorpio's question
FlagOff 37  - Player has not yet taken yellow sphere from grotto
SendToRoom 244 249  - Yellow sphere to shallow grotto
END_Command

Command Enter Sea
AtLocation 152  - Domain of La
FlagOn 34  - Has correctly answered Scorpio's question
FlagOff 37  - Player has not yet taken yellow sphere from grotto
SendToRoom 244 249  - Yellow sphere to shallow grotto
END_Command

Command Enter Sea
AtLocation 152  - Domain of La
PrintMessage 84  - Walk into the water
GoToRoom 153  - Under Water
TurnFlagOFF 35  - Have entered sea
Destroy 314  - Eagle
DoneWithTurn
END_Command

Command West
AtLocation 153  - Under Water
PrintMessage 85  - Player leaves the water
END_Command

Command Exit Sea
AtLocation 153  - Under Water
PrintMessage 85  - Player leaves the water
GoToRoom 152  - Domain of La
DoneWithTurn
END_Command

; Talk to commands

Command Talk to Clerk
AtLocation 3 -  Lobby
PrintMessage 13  - "Any thing you want to ask?"
DoneWithTurn
END_Command

Command Talk to Driver
AtLocation 10
PrintMessage 12  - Informs you that you need to pay your fare.
DoneWithTurn
END_Command

Command Talk to Chicelero
AtLocation 15  -  Muna Town Square
PrintMessage 14  - Jose suggests you examine him
DoneWithTurn
END_Command

Command Talk to Chicelero
AtLocationGT 22  - at pyramid
AtLocationLT 27  - at pyramid
Present 305  - Jose
PrintMessage 2  - Jose wants his payment
DoneWithTurn
END_Command

Command Talk to Chicelero
AtLocation 27  -  Rain Forest
PrintMessage 4  - Jose says he won't take you back to the village
DoneWithTurn
END_Command

;;Astral Woman Related

Command Talk to Woman
FlagOFF 14  - First visit
AtLocation 46  - Astral Meadow
IsCarrying 228  - Potion Vial
PrintMessage 32  - First visit intro
PrintMessage 34  - Information about elevating column & carvings
GoToRoom 45  - Chamber with vial/no exits
TurnFlagON 14 - First visit complete
PrintMessage 35  - Guardian warns player about Turbulare
DoneWithTurn
END_Command

Command Talk to Woman
FlagON 14  - Additional visit
AtLocation 46  - Astral Meadow
IsCarrying 228  - Potion Vial
PrintMessage 33  - Additional visit intro
PrintMessage 34  - Information about elevating column & carvings
GoToRoom 45  - Chamber with vial/no exits
DoneWithTurn
END_Command

Command Talk to Woman
FlagOn 26  - Lion was left behind
FlagOFF 14  - First visit
AtLocation 46  - Astral Meadow
IsNowhere 228  - Vial is broken
PrintMessage 32  - First visit intro
PrintMessage 34  - Information about elevating column & carvings
SendToRoom 227 40  - Niche to room with niche (exits working)
GoToRoom 40  - Chamber with vial/exits present
TurnFlagON 14 - First visit complete
PrintMessage 35  - Guardian warns player about Turbulare
AddToGroup 309  - Lion, friendly
TurnFlagOFF 26  - Lion added back to group
DoneWithTurn
END_Command

Command Talk to Woman
FlagOFF 14  - First visit
AtLocation 46  - Astral Meadow
IsNowhere 228  - Vial is broken
PrintMessage 32  - First visit intro
PrintMessage 34  - Information about elevating column & carvings
SendToRoom 227 40  - Niche to room with niche (exits working)
GoToRoom 40  - Chamber with vial/exits present
TurnFlagON 14 - First visit complete
PrintMessage 35  - Guardian warns player about Turbulare
DoneWithTurn
END_Command

Command Talk to Woman
FlagON 26  - Lion was left behind
FlagON 14  - Additional visit
AtLocation 46  - Astral Meadow
IsNowhere 228  - Vial is broken
PrintMessage 33  - Additional visit intro
PrintMessage 34  - Information about elevating column & carvings
SendToRoom 227 40  - Niche to room with niche (exits working)
GoToRoom 40  - Chamber with vial/exits present
AddToGroup 309  - Lion, friendly
TurnFlagOFF 26  - Lion added back to group
DoneWithTurn
END_Command

Command Talk to Woman
FlagON 14  - Additional visit
AtLocation 46  - Astral Meadow
IsNowhere 228  - Vial is broken
PrintMessage 33  - Additional visit intro
PrintMessage 34  - Information about elevating column & carvings
SendToRoom 227 40  - Niche to room with niche (exits working)
GoToRoom 40  - Chamber with vial/exits present
DoneWithTurn
END_Command

;;Talk to; related to gem and lion

Command Talk to Lion
Present 308  - Hostile Lion
FlagOFF 24  - Player has not already talked to lion
PrintMessage 40  - Player greets the lion
PrintMessage 38  - Lion tells player to return the gem
END_Command

Command Talk to Lion
Present 308  - Hostile Lion
FlagOff 24  - Player has not already talked to the lion
FlagOFF 25  - Player has not been taken by force to the gem chamber
FlagOff 7  - Player has not heard guardian's introduction
PrintMessage 39  - Return to stone chair for pyramid orientation
PrintMessage 48  - You may leave room--should return gem
TurnCounterOff 3  - Player has talked to lion
Destroy 308  - Hostile lion
PutInCurrentRoom 309  - Freindly lion
TurnCounterON 4  - Lion's message until gem returned or player killed
TurnFlagOn 17  - Player has met lion
TurnFlagOn 24  - Player has been forced to the gem chamber by lion
DoneWithTurn
END_Command

Command Talk to Lion
Present 308  - Hostile Lion
FlagOff 24  - Player has not already talked to the lion
FlagOFF 25  - Player has not been taken by force to the gem chamber
PrintMessage 48  - You may leave room--should return gem
TurnCounterOff 3  - Player has talked to lion
Destroy 308  - Hostile lion
PutInCurrentRoom 309  - Freindly lion
TurnCounterON 4  - Lion's message until gem returned or player killed
TurnFlagOn 17  - Player has met lion
TurnFlagOn 24  - Player has been forced to the gem chamber by lion
DoneWithTurn
END_Command

Command Talk to Lion
Present 308  - Hostile Lion
FlagOn 24  - Player has already talked to lion
FlagOn 15  - Emerald not on the pedestal
PrintMessage 59  - Put the emerald on the pedestal
DoneWithTurn
END_Command

;;Talk to Lion -- Domain of Ta

Command Talk to Lion
Present 317  - Regal Lion
FlagOn 48  - Player has previously talked to Lion at Ta
FlagOFF 49  - Have not correctly answered Leo's question
PrintMessage 116  - You have returned--reposes question
END_Command

Command Talk to Lion
Present 317  - Regal Lion
FlagOff 48  - Player has not yet talked to Lion at Ta
FlagOn 17  - Player met lion earlier in game
FlagOFF 49  - Have not correctly answered Leo's question
PrintMessage 111  - Greeting--we meet agian
PrintMessage 113  - Leo's talk about Ta; question
TurnFlagOn 48  - Have now talked to Lion at Ta
END_Command

Command Talk to Lion
Present 317  - Regal Lion
FlagOff 48  - Player has not yet talked to Lion at Ta
FlagOFF 17  - Player has not yet met lion
FlagOFF 49  - Have not correctly answered Leo's question
PrintMessage 112  - Greetings
PrintMessage 113  - Leo's talk about Ta; question
TurnFlagOn 48  - Have now talked to Lion at Ta
END_Command

Command Talk to Lion
Present 317  - Regal Lion
FlagOFF 49  - Have not correctly answered Leo's question
AskQuestion 4  - What is the force felt at image of lion?
AnswerIsCorrect
PrintMessage 114  - Tells player how to get the Blue Sphere
TurnFlagON 49  - Have correctly answered Leo's question
OpenIt 254  - Light columns
DoneWithTurn
END_Command

Command Talk to Lion
Present 317  - Regal Lion
AnswerIsWrong
PrintMessage 115  - Sorry wrong answer--you must leave pyramid
TurnFlagON 50  - Answered question wrong
DoneWithTurn
END_Command

;;Talk to Man (Aquarius)

Command Talk to Man
AtLocation 62
PrintMessage 66  - Player promted to move closer (north)
DoneWithTurn
END_Command

Command Talk to Man
AtLocation 63  - Presence of Ra
FlagOff 31  - Player has not answered question corrctly
FlagOn 28  - Have talked to Aquarius
PrintMessage 67  - Welcome back
END_Command

Command Talk to Man
AtLocation 63  - Presence of Ra
FlagOff 31  - Player has not answered question corrctly
FlagOff 28  - Have not talked to Aquarius
PrintMessage 63
TurnFlagOn 28  - Has talked to Aquarius at least once
END_Command

Command Talk to Man
AtLocation 63
FlagOff 31  - Player has not answered question corrctly
AskQuestion 1  - What is the virtue of Aquarius?
AnswerIsCorrect
PrintMessage 64  - Correct answer, take sphere.
SendToRoom 238 63  - White sphere to Presence of Aquarius
TurnFlagOn 31  - Player has answered Aquarius' question correctly
PlusScore 10
DoneWithTurn
END_Command

Command Talk to Man
AtLocation 63
AnswerIsWrong
PrintMessage 65  - Wrong answer, go to North side of pyramid
TurnFlagOn 33  - Answered question wrong; will be sent to 24
DoneWithTurn
END_Command

;;Talk to Eagle and Crab

Command Talk to Crab
Present 315  - Spunky Crab
PrintMessage 86  - Crab says he snuck in
Destroy 315  - Spunky Crab
DoneWithTurn
END_Command

Command Talk to Eagle
Present 314  - Eagle
AtLocation 152  - Domain of La
FlagOff 34  - Player has not answered Scorpio's question correctly
FlagOn 36  - Player has already spoken to eagle before
PrintMessage 88  - Subsequent conversations with eagle
END_Command

Command Talk to Eagle
Present 314  - Eagle
AtLocation 152  - Domain of La
FlagOff 34  - Player has not answered Scorpio's question correctly
FlagOff 36  - Player hasn't yet talked to eagle
PrintMessage 87  - Eagles first conversation with player
TurnFlagOn 36  - Player has had first conversation with eagle
END_Command

Command Talk to Eagle
Present 314  - Eagle
AtLocation 152  - Domain of La
FlagOff 34  - Player has not answered Scorpio's question correctly
AskQuestion 2  - What is my sign
AnswerIsCorrect
PrintMessage 89  - Tells player where the yellow crystal is
TurnFlagOn 34  - Has answered question correctly
PlusScore 10
Destroy 314  - Eagle
DoneWithTurn
END_Command

Command Talk to Eagle
Present 314  - Eagle
AtLocation 152  - Domain of La
FlagOff 34  - Player has not answered Scorpio's question correctly
AnswerIsWrong
PrintMessage 90  - Tells player to look in the calendar and flys away
Destroy 314  - Eagle
DoneWithTurn
END_Command

;;Talk to Bull

Command Talk to Bull
Present 316  - Bull
AtLocation 93  - Grassy Meadow
FlagOff 39  - Player has not correctly answered Taurus' question
FlagOn 42  - Player has previously spoken to bull
PrintMessage 101  - Bull's response on subsequent visits
END_Command

Command Talk to Bull
Present 316  - Bull
AtLocation 93  - Grassy Meadow
FlagOff 39  - Player has not correctly answered Taurus' question
FlagOff 42  - Player has not yet spoken to bull
PrintMessage 100  - Bull's first conversation with player
END_Command

Command Talk to Bull
Present 316  - Bull
AtLocation 93  - Grassy Meadow
FlagOff 39  - Player has not correctly answered Taurus' question
AskQuestion 3  - What does the circle with the dot represent?
AnswerIsCorrect
PrintMessage 102  - Congradulations, sphere is in the cave
TurnFlagOn 39  - Has correctly answered Taurus' question
Destroy 316  - Bull
DoneWithTurn
END_Command

Command Talk to Bull
Present 316  - Bull
AtLocation 93  - Grassy Meadow
FlagOff 39  - Player has not correctly answered Taurus' question
AnswerIsWrong
PrintMessage 103  - Wrong answer, you must go to band of carvings
Destroy 316  - Bull
GoToRoom 49  - Standing by west door
TurnFlagOff 41  - Reset Flag to control placement of Bull in Meadow.
TurnFlagOn 43  - Player has been sent to 49-flag checks status of circle
TurnFlagOn 44  - Player has been sent to 49-flag checks status of square
TurnFlagOn 45  - Player has been sent to 49-flag checks status of flashlight
DoneWithTurn
END_Command

; Bus driver related

Command Pay Driver With Coins
AtLocation 10  - Bus to Muna
IsCarrying 203  - Coins
GoToRoom 11 - Under Way to Muna
TurnCounterOFF 1
SendToRoom 203 2 -  Coins to Hotel Room
DoneWithTurn
END_Command

Command Pay Driver With Any
AtLocation 10  - Bus to Muna
NOT NounIsNumber  203  - Not Coins
ObjectPresent
PrintMessage 8  - "That won't do"  noun looks at object
DoneWithTurn
END_Command

Command Pay Driver With Any
AtLocation 10  - Bus to Muna
NOT NounIsNumber  203  - Not Coins
NOT ObjectPresent
PrintMessage 11  - You must have the Object before you can give it
DoneWithTurn
END_Command

Command Pay Driver
AtLocation 10 -  Bus to Muna
PrintMessage 5  - Must pay driver with something
DoneWithTurn
END_Command

; Bus Driver Related

Command Give Coins to Driver
AtLocation 10  - Bus to Muna
IsCarrying 203  - Coins
GoToRoom 11 - Under Way to Muna
TurnCounterOFF 1
SendToRoom 203 2  -  Coins to Hotel Room
DoneWithTurn
END_Command

Command Give Any to Driver
AtLocation 10  - Bus to Muna
NOT NounIsNumber  203  - Not Coins
ObjectPresent
PrintMessage 6  - "That won't do"   object looks at noun
DoneWithTurn
END_Command

Command Give Any to Driver
AtLocation 10  - Bus to Muna
NOT NounIsNumber  203  - Not Coins
NOT ObjectPresent
PrintMessage 11  - You must have the $Object before you can give it
DoneWithTurn
END_Command

; Remove Moss commands

Command Remove Moss
AtLocation 23  - West Side of Pyramid
OpenIt 214  - Rough Place
TurnFlagOn 10  - Rough place is open
Destroy 222  - Moss
PrintMessage 15 -  Re-exaimine and study wall
DoneWithTurn
END_Command

Command Remove Moss
AtLocation 24  - North Side of Pyramid
OpenIt 216  - Rough Spot
TurnFlagOn 11  - Rough Spot is open
Destroy 222  - Moss
PrintMessage 15 -  Re-exaimine and study wall
DoneWithTurn
END_Command

Command Remove Moss
AtLocation 25  - East Side of Pyramid
OpenIt 220  - Irregular Spot
TurnFlagOn 12  - Irregular Spot is open
Destroy 222  - Moss
PrintMessage 15 -  Re-exaimine and study wall
DoneWithTurn
END_Command

Command Remove Moss
AtLocation 26  - South Side of Pyramid
OpenIt 218  - Irregular Place
TurnFlagOn 13  - Irregular Place is open
Destroy 222  - Moss
PrintMessage 15 -  Re-exaimine and study wall
DoneWithTurn
END_Command

; Open Commands

;;Regarding cleaning the spot & place on the pyramid wall

Command Open Spot
AtLocation 24  - North side of pyramid
TurnFlagOn 11  - Rough spot is open
PrintMessage 15  - Moss removed--examine and study image
Destroy 222  - Moss & Lichen
END_Command

Command Open Spot
AtLocation 25  - East side of Pyramid
TurnFlagOn 12  - Irregular Spot is open
PrintMessage 15  - Moss removed--examine and study image
Destroy 222  - Moss & Lichen
END_Command

Command Open Place
AtLocation 23  - West side of pyramid
TurnFlagOn 10  - Rough Place is open
PrintMessage 15  - Moss removed--examine and study image
Destroy 222  - Moss & Lichen
END_Command

Command Open Place
AtLocation 26  - South side of pyramid
TurnFlagOn 13  - Irregular Place is open
PrintMessage 15  - Moss removed--examine and study image
Destroy 222  - Moss & Lichen
END_Command

;;Related to Stone Box

Command Open Box
Present 229  - Stone Box
FlagOn 15  - Emerald is not on the pedestal
FlagOff 21  - Box is closed
PrintMessage 55  - You cant't open the box, maybe the Emerald is problem
DoneWithTurn
END_Command

Command Open Box
Present 229  - Stone Box
FlagOff 15  - Emerald is on the pedestal
FlagOff 21  - Box is closed
TurnFlagOn 21  - Box is now open
END_Command

; Close Commands

;;Regarding Stone Box

Command Close Box
Present 229  - Stone Box
FlagOn 21  - Box is open
TurnFlagOff 21  - Box is now closed
TurnFlagOff 22  - When on player has been told box is open
END_Command

; Read Image Commands

Command Read Bull
AtLocation 23  - West Side of Pyramid
IsOpen 214  - Rough Place
NounIsNumber 215  - Carved Bull
FlagOff 2  - Image of Bull has not been read
PlusScore 10
TurnFlagOn 2  - Image of Bull has been read
END_Command

Command Read Man
AtLocation 24  - North Side of Pyramid
IsOpen 216  - Rough Spot
NounIsNumber 217  - Carved Man
FlagOff 3  -  Image of Man has not been read
PlusScore 10
TurnFlagOn 3  -  Image of Man has been read
END_Command

Command Read Eagle
AtLocation 25  - East Side of Pyramid
IsOpen 220  - Irregular spot
NounIsNumber 221  - Carved Eagle
FlagOff 4  -  Image of Eagle has not been read
PlusScore 10
TurnFlagOn 4  -  Image of Eagle has been read
END_Command

Command Read Lion
AtLocation 26  - South Side of Pyramid
IsOpen 218  - Irregular place
NounIsNumber 219  - Carved Lion
FlagOff 5  -  Image of Lion has not been read
PlusScore 10
TurnFlagOn 5  -  Image of Lion has been read
END_Command

; Follow Commands

;;Follow Jose

Command Follow Chicelero
Present 305  -  Jose is present
AtLocation 15  - Muna Town Square
  OR
AtLocation 21  - Rainforest Trail
  OR
AtLocation 22  - Rainforest Trail
PrintMessage 23  - Go East
DoneWithTurn
END_Command

Command Follow Chicelero
AtLocation 15  - Muna Town Square
  OR
AtLocation 21  - Rainforest Trail
  OR
AtLocation 22  - Rainforest Trail
PrintMessage 9  - Jose is not here
DoneWithTurn
END_Command

; Pay Jose Commands

Command Pay Chicelero with Bills
FlagOn 1  - Jose has asked for payment
ObjectPresent  - Bills are present
NOUNPresent  - Jose is present
PrintMessage 7  - Jose thanks you and disappears
SendToRoom 207 0 - American Bills go Location 0
SendToRoom 305 0   - Send Jose to Location 0
TurnFlagOff 1  -  Jose has been paid
TurnCounterOFF 1  - so Jose won't come back and get you.
DoneWithTurn
END_Command

Command Pay Chicelero Any
AtLocationGT 14
AtLocationLT 23   - Before reaching the pyramid
PrintMessage 17  -  Won't accept payment until pyramid is reached
END_Command

Command Pay Chicelero Any
FlagOn 1  - Jose has asked for payment
NOT ObjectPresent  - Object is not present
NOUNPresent  - Jose is present
PrintMessage 11  - You must have the Object to give it
DoneWithTurn
END_Command

Command Pay Chicelero Any
FlagOn 1  - Jose has asked for payment
ObjectPresent  - Object is present
NOT NOUNPresent  - Jose is not present
PrintMessage 9  - The Noun is not here
DoneWithTurn
END_Command

Command Pay Chicelero with Any
FlagOn 1  - Jose has asked for payment
ObjectPresent  - Object is present
NOUNPresent  - Jose is present
PrintMessage 8  - Noun looks at object: that won't do
DoneWithTurn
END_Command

; Give commands

;;Jose and Bills

Command Give Bills to Chicelero
ReDirectTo Pay Chicelero with Bills
END_Command

Command Give Any to Chicelero
ReDirectTo Pay Chicelero with Any
END_Command

;;Kinkajou and sandwich

Command Give Sandwich to Kinkajou
Present 313  - Kinkajou
IsCarrying 209  - Sandwich
PrintMessage 69  - Kinkajou runs away with the sandwich
Destroy 313  - Kinkajou
Destroy 209  - Sandwich
DoneWithTurn
END_Command

; Give commands

;;Sandwich to Kinkajou

Command Offer Sandwich to Kinkajou
ReDirectTo Give Sandwich to Kinkajou
END_Command

;Climb Commands

;;Climbing Pyramid

Command Climb Place
AtLocation 23  - West side of pyramid
  OR
AtLocation 26  - South side of pyramid
PrintMessage 22  - Begin to climb the pyramid and drop to ground
DoneWithTurn
END_Command

Command Climb Spot
AtLocation 24  - North side of pyramid
  OR
AtLocation 25  - East side of Pyramid
PrintMessage 22  - Begin to climb the pyramid and drop to ground
DoneWithTurn
END_Command

; Put Commands

;;Open Pyramid Door

Command Put Star in Recess
AtLocation 25 - East side of pyramid w/ door closed
NounPresent
ObjectPresent
ObjectIsNumber 224  - Star-shaped Recess
GoToRoom 28  -  East side with open door
SendToRoom 224 28  -  Put Recess in east side open door room
PrintMessage 18  - Pyramid door opens
END_Command

Command Put Star in Recess
AtLocation 30  - Entrance chamber with door closed
NounPresent
ObjectPresent
ObjectIsNumber 224  - Star-shaped Recess
IsCarrying 233  - The large gem
PrintMessage 36  - The door opens part way
GoToRoom 29 -  Entrance chamber w/ open door
SendToRoom 224 29  -  Put Recess in entrance chamber w/ open door
SendToRoom 202 224  - Put Star in Recess
DoneWithTurn
END_Command

Command Put Star in Recess
AtLocation 30  - Entrance chamber with door closed
NounPresent
ObjectPresent
ObjectIsNumber 224  - Star-shaped Recess
Not IsCarrying 233  - Is not carrying the large gem
FlagOn 15  - Gem is not on the pedestal
PrintMessage 43  - The door won't open
SendToRoom 202 224  - Put Star in Recess
DoneWithTurn
END_Command

Command Put Star in Recess
AtLocation 30  - Entrance chamber with door closed
NounPresent
ObjectPresent
ObjectIsNumber 224  - Star-shaped Recess
GoToRoom 29 -  Entrance chamber w/ open door
SendToRoom 224 29  -  Put Recess in entrance chamber w/ open door
PrintMessage 21  - Pyramid door opens
END_Command

;;Put Vial in Niche

Command Put Vial in Niche
FlagON 26  - Lion left behind
AtLocation 45  - Vial chamber with no exits
IsCarrying 228  - Vial
Present 227  - Niche
SendToRoom 227 40  - Niche to new chamber
GoToRoom 40  - Chamber with vial
AddToGroup 309  - Lion, friendly
TurnFlagOFF  - Lion rejoined with player
END_Command

Command Put Vial in Niche
AtLocation 45  - Vial chamber with no exits
IsCarrying 228  - Vial
Present 227  - Niche
SendToRoom 227 40  - Niche to new chamber
GoToRoom 40  - Chamber with vial
END_Command

;;Large Gem Related

Command Put Gem on Pedestal
AtLocation 39  - Chamber with the large gem
FlagOn 15  - Large Gem not on the pedestal
NOT IsCarrying 233  - Large Gem
PrintMessage 59  - Have to have gem first
DoneWithTurn
END_Command

Command Put Gem on Pedestal
AtLocation 39  - Chamber with the large gem
FlagOn 15  - Large Gem not on the pedestal
IsCarrying 233  - Large Gem
FlagOFF 18  - Player has not yet put gem on the pedestal
PlusScore 10
TurnFlagON 18  - Player has put gem on pedestal at least once
END_Command

Command Put Gem on Pedestal
AtLocation 39  - Chamber with the large gem
FlagOn 15  - Large Gem not on the pedestal
IsCarrying 233  - Large Gem
Destroy 309  - Fierce Lion - Friendly
TurnCounterOFF 2  - Gem is on pedestal
TurnCounterOFF 4  - Gem is on pedestal
TurnCounterOFF 5  - Gem is on pedestal
PrintMessage 37  - Thank you
END_Command

Command Put Gem on Pedestal
AtLocation 39  - Chamber with the large gem
FlagOn 15  - Large Gem not on the pedestal
IsCarrying 233  - Large Gem
Present 308  - Fierce Lion - Hostile
Destroy 308  - Fierce Lion - Hostile
PrintMessage 49  - Lion has vanished
END_Command

Command Put Gem on Pedestal
AtLocation 39  - Chamber with the large gem
FlagOn 15  - Large Gem not on the pedestal
IsCarrying 233  - Large Gem
Present 311  - Pyramid Guardian
Destroy 311  - Pyramid Guardian
PrintMessage 58  -  Guardian has disappeared
END_Command

Command Put Gem on Pedestal
AtLocation 39  - Chamber with the large gem
FlagOn 15  - Large Gem not on the pedestal
IsCarrying 233  - Large Gem
TurnFlagOFF 15  - Gem is on pedestal
END_Command

;;Relating to elevating column

Command Put Square in Square Recess
FlagOn 20  - Player is on Platform and it is ready
FlagOFF 15  - Gem is on the pedestal
Present 231  - Stone Square
Present 236  - Square Recess
ObjectIsNumber 236  - Square Recess
AtLocation 44
PrintMessage 53  - Player descends on the elevating column
GoToRoom 47  - Lower Level Central Chamber
SendToRoom 234 47  - Circular Platform to Lower Level Central Chamber
END_Command

Command Put Square in Square Recess
FlagOff 20  - Player is not on Platform or it is not ready
FlagOFF 15  - Gem is on the pedestal
Present 231  - Stone Square
Present 236  - Square Recess
ObjectIsNumber 236  - Square Recess
AtLocation 44  - Half Sphere Chamber
  or
AtLocation 47  - Lower Level Central Chamber
PrintMessage 52  - Propmts player to stand on the platform
DoneWithTurn
END_Command

Command Put Square in Circular Recess
Present 231  - Stone Square
Present 235  - Circular Recess
ObjectIsNumber 235  - Circular Recess
PrintMessage 57  - It doesn't fit.
DoneWithTurn
END_Command

Command Put Circle in Circular Recess
FlagOff 20  - Player is not on Platform or it is not ready
FlagOFF 15  - Gem is on the pedestal
Present 230  - Stone Circle
Present 235  - Circular Recess
ObjectIsNumber 235  - Circular Recess
AtLocation 44  - Half Sphere Chamber
  or
AtLocation 47  - Lower Level Central Chamber
PrintMessage 52  - Propmts player to stand on the platform
END_Command

Command Put Circle in Circular Recess
FlagOn 20  - Player is on Platform and it is ready
Present 230  - Stone circle
Present 235  -  Circular Recess
ObjectIsNumber 235  - Circular Recess
AtLocation 47  - Lower Level Central Chamber
PrintMessage 54  - Player rides column up to new chamber
GoToRoom 44  - Player is moved to Half Sphere Chamber
SendToRoom 234 44  - Circular Platform to Half Sphere Chamber
SendToRoom 230 235  - Stone circle to circular recess
DoneWithTurn
END_Command

Command Put Circle in Circular Recess
FlagOn 20  - Player is on Platform and it is ready
Present 230  - Stone circle
Present 235  -  Circular Recess
ObjectIsNumber 235  - Circular Recess
AtLocation 44  - Half Sphere Chamber
IsCarrying 238  - White Sphere
IsCarrying 240  - Red sphere
IsCarrying 242  - Blue Sphere
IsCarrying 244  - Yellow Sphere
PrintMessage 81  - Initiation
GoToRoom 180  - Upper Initiation Chamber
SendToRoom 234 180  - Circular platform to Upper Initiation Chamber
DoneWithTurn
END_Command

Command Put Circle in Square Recess
Present 230  - Stone Circle
Present 236  - Square Recess
ObjectIsNumber 236  - Square Recess
PrintMessage 57  - It doesn't fit.
DoneWithTurn
END_Command

; Replace Commands

;;Replace Vial

Command Replace Vial
FlagOn 26  - Lion has been left begind
AtLocation 45  - Vial chamber with no exits
IsCarrying 228  - Vial
Present 227  - Niche
SendToRoom 228 227  - Vial to niche
SendToRoom 227 40  - Niche to new chamber
GoToRoom 40  - Chamber with vial
AddToGroup 309  - Lion Friendly
TurnFlagOFF  - Lion rejoined with player
DoneWithTurn
END_Command

Command Replace Vial
AtLocation 45  - Vial chamber with no exits
IsCarrying 228  - Vial
Present 227  - Niche
SendToRoom 228 227  - Vial to niche
SendToRoom 227 40  - Niche to new chamber
GoToRoom 40  - Chamber with vial
DoneWithTurn
END_Command

; Return Commands

;;Return Vial

Command Return Vial
ReDirectTo Replace Vial
END_Command

; Sit Commands

;;Sit in Chair--Instruction Chamber

Command Sit in Chair
AtLocation 37  - Instruction Chamber
FlagOff 9 -  Player has not yet sat in chair
PlusScore 10  - 10 points for sitting in chair
TurnFlagOn 9  - Player has sat in stone chair in instruction room
END_Command

Command Sit in Chair
AtLocation 37  - Instruction Chamber
FlagOff 7  - Have not heard welcome speech yet.
FlagOn 2  - Bull has been read
FlagOn 3  - Man has been read
Flagon 4  - Eagle has been read
Flagon 5  - Lion has been read
PrintMessage 19  - Guardian's Welcome speech
SendToRoom 306 0  - Remove guardian
PromptForYES
PrintMessage 24  - Explains about crystal spheres (orientation speech)
TurnFlagOn 7  - Have heard welcome speech.
TurnFlagOn 19  - Has heard orientation speech
DoneWithTurn
END_Command

Command Sit in Chair
AtLocation 37  - Instruction Chamber
FlagOff 7  - Have not heard welcome speech yet.
FlagOn 2  - Bull has been read
FlagOn 3  - Man has been read
Flagon 4  - Eagle has been read
Flagon 5  - Lion has been read
PrintMessage 27  - Guardian sends player back to hotel
GoToRoom 2  -  Go to hotel room.
TurnFlagOn 7  - Have heard welcome speech.
DoneWithTurn
END_Command

Command Sit in Chair
AtLocation 37  - Instruction Chamber
FlagOff 7  - Have not heard welcome speech yet.
PrintMessage 19  - Guardian's Welcome speech
SendToRoom 306 0  - Remove guardian
PromptForYES
PrintMessage 26  - Guardian sends player out to study images
TurnFlagOn 7  - Have heard welcome speech.
DoneWithTurn
END_Command

Command Sit in Chair
AtLocation 37  - Instruction Chamber
FlagOff 7  - Have not heard welcome speech yet.
PrintMessage 27  - Guardian sends player back to hotel
GoToRoom 2  - Go to hotel room.
TurnFlagOn 7  - Have heard welcome speech.
DoneWithTurn
END_Command

Command Sit in Chair
AtLocation 37  - Instruction Chamber
FlagOn 7  - Have already heard welcome speech
FlagOn 2  - Bull has been read
FlagOn 3  - Man has been read
FlagOn 4  - Eagle has been read
FlagOn 5  - Lion has been read
PrintMessage 25  -  Guardian's rewelcome
PromptForYES
PrintMessage 24  - Explains about crystal spheres (orientation speech)
TurnFlagOn 19  - Has heard orientation speech
DoneWithTurn
END_Command

Command Sit in Chair
AtLocation 37  - Instruction Chamber
FlagOn 7  - Have already heard welcome speech
FlagOn 2  - Bull has been read
FlagOn 3  - Man has been read
FlagOn 4  - Eagle has been read
FlagOn 5  - Lion has been read
PrintMessage 27  - Guardian sends player back to hotel
GoToRoom 2  -  Return to Hotel Room
DoneWithTurn
END_Command

Command Sit in Chair
AtLocation 37  - Instruction Chamber
FlagOn 7  - Have already heard welcome speech
PrintMessage 25  -  Guardian's rewelcome speech
PromptForYES
PrintMessage 26  - Guardian sends player out to study images
DoneWithTurn
END_Command

Command Sit in Chair
AtLocation 37  - Instruction Chamber
FlagOn 7  - Have already heard welcome speech
PrintMessage 27  - Guardian sends player back to hotel
GoToRoom 2  -  Return to Hotel Room
DoneWithTurn
END_Command

; Push Commands 

;;Narrow Band of Carvings

Command Push Band
Present 226  - Narrow Band
FlagOff 8 -  Have not yet seen msg 28: describes circle & square
PlusScore 10  - 10 points for touching band
TurnFlagOn 8  - No more points for touching band
END_Command

Command Push Band
Present 226  - Narrow Band
PrintMessage 28  - meaning of circle and square
DoneWithTurn
END_Command

;;Push Door

Command Push Door
AtLocation 61  - Entrance chamber: Ra
SendToRoom 237 60  - White door to entrance chamber to Ra
END_Command

Command Push Door
AtLocation 91  - Entrance chamber: Mu (closed)
SendToRoom 239 90  - Red door to Entrance Chamber: Mu (open)
END_Command

Command Push Door
AtLocation 121  - Entrance Chamber: Ta (closed)
SendToRoom 241 120  - Blue door to Entrance Chamber: Ta (open)
END_Command

Command Push Door
AtLocation 151  - Entrance Chamber: La (Closed)
SendToRoom 243 150  - Yellow Door to Entrance Chamber: La (open)
END_Command

;;Push circle

Command Push Circle
FlagOn 20  - Player is on Platform and it is ready
IsLocated 230 235  - Stone circle is in circular recess
Present 235  -  Circular Recess
AtLocation 44  - Half Sphere Chamber
IsCarrying 238  - White Sphere
IsCarrying 240  - Red sphere
IsCarrying 242  - Blue Sphere
IsCarrying 244  - Yellow Sphere
PrintMessage 81  - Initiation
GoToRoom 180  - Upper Initiation Chamber
SendToRoom 234 180  - Circular platform to Upper Initiation Chamber
DoneWithTurn
END_Command

;;Light Columns

Command Push Columns
NounIsNumber 254  - Light Columns
Present 254  - Light columns
IsOpen 254  - Light Columns
PrintMessage 120  - Your hand goes in the column
DoneWithTurn
END_Command

; Get Commands

;;Get Potion Vial

Command Get Vial
NounIsNumber 228
Present 309  - Lion, friendly
AtLocation 40  - Chamber with potion vial
Present 228  - Jade Vial
RemoveFromGroup 309  - Lion, Friendly
TurnFlagOn 26  - Lion has been left behind
SendToRoom 228 1  - Give the player the jade vial
SendToRoom 227 45  - niche to new chamber
GoToRoom 45  - Chamber with potion vial & no exits
PrintMessage 61  - You are now carrying the $NOUN$
DoneWithTurn
END_Command

Command Get Vial
NounIsNumber 228
AtLocation 40  - Chamber with potion vial
Present 228  - Jade Vial
SendToRoom 228 1  - Give the player the jade vial
SendToRoom 227 45  - niche to new chamber
GoToRoom 45  - Chamber with potion vial & no exits
PrintMessage 61  - You are now carrying the $NOUN$
DoneWithTurn
END_Command

;;Large Gem related

Command Get Gem
FlagOff 15  - Gem is on pedestal
TurnCounterOn 2  - Gem is not on the pedestal
TurnFlagOn 15  - Gem is not on the pedestal
TurnFlagOn 16  - Gem has been removed from pedestal, may have been returned
END_Command

;;Flashlight, Star, and Square with Kinkajou

Command Get flashlight
AtLocation 25  - east side of pyramid
Present 201  - flashlight
Present 313  - Kinkajou
PrintMessage 70  - Kinkajou won't let you get it
DoneWithTurn
END_Command

Command Get Star
AtLocation 25  - east side of pyramid
Present 202  - Stone Star
Present 313  - Kinkajou
PrintMessage 70  - Kinkajou won't let you get it
DoneWithTurn
END_Command

Command Get Square
AtLocation 25  - east side of pyramid
Present 231  - Stone Square
Present 313  - Kinkajou
PrintMessage 70  - Kinkajou won't let you get it
DoneWithTurn
END_Command

;;White Crystal Sphere

Command Get Sphere
AtLocation 63  - Presence of Aquarius
NounIsNumber 238  - White Sphere
Present 238  - White sphere
FlagOff 30  - Player has not taken white sphere yet
FlagOn 31  Player has answered correctly Aquarius' question
PrintMessage 68  - Take the sphere, you may go
SendToRoom 238 1  - Player gets white sphere
DoneWithTurn
END_Command

;;Yellow Crystal Sphere

Command Get Sphere
NounIsNumber 244  - Yellow Sphere
AtLocation 153  - Under Water: In the sea
Present 244  - Yellow Sphere
FlagOff 37  - Player hasn't yet taken sphere from grotto
FlagOn 34  - Player has correctly answered Scorpio's question
TurnFlagOn 37  - Player has now taken yellow sphere from grotto
END_Command

;;Blue Crystal Sphere

Command Get Sphere
NounIsNumber 242  - Blue Sphere
AtLocation 124  - Light columns
IsOpen 254  - Light Columns are open
IsLocated 242 254  - Blue sphere is in Light columns
PrintMessage 119  - You reach in and take the sphere
END_Command

;Put ___ in Pack commands

;;Put Vial in Pack

Command Put Vial in Pack
NounIsNumber 228
Present 309  - Lion, friendly
AtLocation 40  - Chamber with potion vial
Present 228  - Jade Vial
RemoveFromGroup 309  - Lion, Friendly
TurnFlagOn 26  - Lion has been left behind
SendToRoom 228 205  - Put vial in pack
SendToRoom 227 45  - niche to new chamber
GoToRoom 45  - Chamber with potion vial & no exits
PrintMessage 61  - You are now carrying the $NOUN$
DoneWithTurn
END_Command

Command Put Vial in Pack
NounIsNumber 228
AtLocation 40  - Chamber with potion vial
Present 228  - Jade Vial
SendToRoom 228 205  - Put vial in pack
SendToRoom 227 45  - niche to new chamber
GoToRoom 45  - Chamber with potion vial & no exits
PrintMessage 61  - You are now carrying the $NOUN$
DoneWithTurn
END_Command

;;Put Gem in Pack

Command Put Gem in Pack
ReDirectTo Get Gem
END_Command

;;Flashlight, Star, and Square with Kinkajou

Command Put Flashlight in Pack
ReDirectTo Get Flashlight
END_Command

Command Put Star in Pack
ReDirectTo Get Star
END_Command

Command Put Square in Pack
ReDirectTo Get Square
END_Command

Command Put Sphere in Pack
AtLocation 63  - Presence of Aquarius
NounIsNumber 238  - White Sphere
Present 238  - White sphere
FlagOff 30  - Player has not taken white sphere yet
FlagOn 31  Player has answered correctly Aquarius' question
PrintMessage 68  - Take the sphere, you may go
SendToRoom 238 205  - Player puts white sphere in pack
DoneWithTurn
END_Command

;;Yellow Crystal Sphere

Command Put Sphere in Pack
NounIsNumber 244  - Yellow Sphere
AtLocation 153  - Under Water: In the sea
Present 244  - Yellow Sphere
FlagOff 37  - Player hasn't yet taken sphere from grotto
FlagOn 34  - Player has correctly answered Scorpio's question
TurnFlagOn 37  - Player has now taken yellow sphere from grotto
SendToRoom 244 205  - Yellow Sphere to Pack
DoneWithTurn
END_Command

; Drink Commands

;;Jade Vial sequence

Command Drink Vial
AtLocation 45  - Chamber with vial/no exits
IsCarrying 228  - Jade Vial
PrintMessage 29  - You $VERB$ the contents and wake up somewhere else.
GoToRoom 46  - Astral Meadow
DoneWithTurn
END_Command

; Taste Commands

;;Relating to Potion Vial

Command Taste Potion
AtLocation 45  - chamber with vial & no exits
IsCarrying 228  - Jade Vial
PrintMessage 29  - You $VERB$ the contents and wake up somewhere else.
GoToRoom 46  - Astral Meadow
DoneWithTurn
END_Command

; Feed commands

;;Kinkajou

Command Feed Sandwich to Kinkajou
Present 313  - Kinkajou
IsCarrying 209  - Sandwich
PrintMessage 69  - Kinkajou runs away with sandwich
Destroy 313  - Kinkajou
Destroy 209  - Sandwich
DoneWithTurn
END_Command

; Smell Commands

;;Regarding Potion Vial

Command Smell Potion
AtLocation 45  - chamber with vial & no exits
IsCarrying 228  - Jade Vial
PrintMessage 31  - The fumes overcome you and you wake up somewhere else.
GoToRoom 46  - Astral Meadow
DoneWithTurn
END_Command

; Drop Commands

;;Regarding Potion Vial

Command Drop Vial
AtLocation 45  - chamber with vial & no exits
IsCarrying 228  - Jade Vial
PrintMessage 30  - The vial drops to the floor and breaks
PrintMessage 31  - The fumes overcome you and you wake up somewhere else.
GoToRoom 46  - Astral Meadow
Destroy 228  - the vial is sent to location 0
DoneWithTurn
END_Command

; Break Commands

;;Regarding Potion Vial

Command Break Vial
ReDirectTo Drop Vial
END_Command

; Stand and Step Commands

;;Relating to elevating column

Command Stand on Platform
Present 234  - Circular Platform
FlagOn 20  - Player is on platform & it is ready
PrintMessage 51  - You step off the platform
ToggleFlag 20  - Player moves on or off platform and it is ready or not
DoneWithTurn
END_Command

Command Stand on Platform
Present 234  - Circular Platform
FlagOff 20  - Player is not on platform or it is not ready
PrintMessage 50  - You step on the platform
ToggleFlag 20  - Player moves on or off platform and it is ready or not
DoneWithTurn
END_Command

; Move Commands

;;Relating to elevating column

Command Move off Platform
Present 234  - Circular Platform
FlagOn 20  - Player is on platform & it is ready
PrintMessage 51  - You step off the platform
ToggleFlag 20  - Player moves on or off platform and it is ready or not
DoneWithTurn
END_Command

Command Move off Platform
Present 234  - Circular Platform
FlagOff 20  - Player is not on platform or it is not ready
PrintMessage 50  - You step on the platform
ToggleFlag 20  - Player moves on or off platform and it is ready or not
DoneWithTurn
END_Command

; RA MU TA LA

;;Ra

Command Ra
AtLocation 48
SendToRoom 237 52  - White door to standing by north door
END_Command

Command Ra
AtLocation 61  - Entrance Chamber: Domain of Ra
PrintMessage 76  - You chant Ra but nothing happens
DoneWithTurn
END_Command

Command Ra
AtLocation 49  - West Door
  OR
AtLocation 50  - South Door
  OR
AtLocation 51  - East Door
PrintMessage 78  - Try the name of another force
DoneWithTurn
END_Command

Command Ra
AtLocation 91  - Entrance Chamber: Mu (closed)
 OR
AtLocation 121  - Entrance Chamber: Ta (closed)
 OR
AtLocation 151  - Entrance Chamber: La (closed)
PrintMessage 80  - Wrong force name or tactic
DoneWithTurn
END_Command

Command Ra
NOT AtLocation 61  - Entrance Chamber: Domain of Ra
 OR
AtLocationGT 51
 OR
AtLocationLT 48
PrintMessage 79  - Sorry, that won't work here
DoneWithTurn
END_Command

;;Mu

Command Mu
AtLocation 49  - Standing by West Door (closed)
SendToRoom 239 53  - Red Door to Standing by West Door (open)
END_Command

Command Mu
AtLocation 91  - Entrance chamber: Domain of Mu
PrintMessage 76  - You chant Mu but nothing happens
DoneWithTurn
END_Command

Command Mu
AtLocation 48  - By North Door
  OR
AtLocation 50  - By South Door
  OR
AtLocation 51  - By East Door
PrintMessage 78  - Try the name of another force
DoneWithTurn
END_Command

Command Mu
AtLocation 61  - Entrance Chamber: Ra (closed)
 OR
AtLocation 121  - Entrance Chamber: Ta (closed)
 OR
AtLocation 151  - Entrance Chamber: La (closed)
PrintMessage 80  - Wrong force name or tactic
DoneWithTurn
END_Command

Command Mu
NOT AtLocation 91  - Entrance Chamber: Mu
 OR
AtLocationGT 51
 OR
AtLocationLT 48
PrintMessage 79  - Sorry, that won't work here.
DoneWithTurn
END_Command

;;Ta

Command Ta
AtLocation 50  - By South door (closed)
SendToRoom 241 54  - Blue door to Standing by south door (open)
END_Command

Command Ta
AtLocation 121  - Entrance chamber: Domain of Ta
PrintMessage 76  - You chant Ta but nothing happens
DoneWithTurn
END_Command

Command Ta
AtLocation 48  - By north door
  OR
AtLocation 49  - by west door
  OR
AtLocation 51  - By East door
PrintMessage  78  - Try the name of another force
DoneWithTurn
END_Command

Command Ta
AtLocation 61  - Entrance Chamber: Ra (closed)
 OR
AtLocation 91  - Entrance Chamber: Mu (closed)
 OR
AtLocation 151  - Entrance Chamber: La (closed)
PrintMessage 80  - Wrong force name or tactic
DoneWithTurn
END_Command

Command Ta
NOT AtLocation 121  - Entrance Chamber: Ta
 OR
AtLocationGT 51
 OR
AtLocationLT 48
PrintMessage 79  - Sorry, that won't work here
DoneWithTurn
END_Command

;;La

Command La
AtLocation 51  - Standing by the east door
SendToRoom 243 55  - Yellow door to standing by east door (open)
END_Command

Command La
AtLocation 151  - Entrance chamber: Domain of La
PrintMessage 76  - You chant La but nothing happens
DoneWithTurn
END_Command

Command La
AtLocation 48  - North Door
  OR
AtLocation 49  - West door
  OR
AtLocation 50  - South door
PrintMessage 78  - Try the name of another force
DoneWithTurn
END_Command

Command La
AtLocation 61  - Entrance Chamber: Ra (closed)
 OR
AtLocation 91  - Entrance Chamber: Mu (closed)
 OR
AtLocation 121  - Entrance Chamber: Ta (closed)
PrintMessage 80  - Wrong force or tactic
DoneWithTurn
END_Command

Command La
NOT AtLocation 151  Entrance Chamber: domain of La
 OR
AtLocationGT 51
 OR
AtLocationLT 48
PrintMessage 79  - sorry, that won't work here
DoneWithTurn
END_Command

; Attack commands

;;Attack Jose

Command Attack Chicelero
Present 305  - Chicelero
PrintMessage 122  - You attack Jose and slip into darkness
Destroy 305  - Jose
Destroy 200  - Wallet
Destroy 207  - Currency
SendToRoom 203 2  - Coins to Hotel Room
TurnCounterOFF 1  - So Jose or bus driver won't deal with you unkindly
TurnFlagOFF 1  - Player has been killed by Jose
TurnFlagON 51  - Player has been killed by Jose
MinusScore 10
KillPlayer  - Player tried to attack Jose so was killed
END_Command

;;Pyramid Guardian

Command Attack Guardian
NounIsNumber 306  - Pyramid Guardian
Present 306  - Pyramid Guardian
PrintMessage 20  - Your action was unappropriate
DoneWithTurn
END_Command

;;Large Man

Command Attack Man
NounIsNumber 312  - Large Man
AtLocation 63  - Presence of Aquarius
PrintMessage 20  - Your Action was unappropriate
MinusScore 10
DoneWithTurn
END_Command

;;Kinkajou

Command Attack Kinkajou
Present 313  - Kinkajou
AtLocation 25  - East side of Pyramid
NOT ObjectPresent
PrintMessage 71  - You attack the kinkajou with your hands, it snarls...
DoneWithTurn
END_Command

Command Attack Kinkajou with Any
Present 313  - Kinkajou
AtLocation 25  - East side of Pyramid
ObjectPresent
PrintMessage 72  - You attack the kinkajou with $OBJECT$, it snarls
DoneWithTurn
END_Command

;;Attack Bull

Command Attack Bull
Present 316  - Imposing Bull
PrintMessage 97  - Bull crosses river leaving player alone in the meadow
Destroy 316  - Bull
TurnFlagOff 38  - Has attacked bull
MinusScore 10
DoneWithTurn
END_Command

;;Attack Lion

Command Attack Lion
Present 317  - Regal Lion
NounIsNumber 317  - Regal Lion
PrintMessage 110
MinusScore 10
DoneWithTurn
END_Command

;;Attack Eagle

Command Attack Eagle
Present 314  - Eagle
NounIsNumber 314  - Eagle
PrintMessage 91  - Eagle flys away in disgust
Destroy 314  - Eagle
TurnFlagOff 35  - Eagle has been attacked
MinusScore 10
DoneWithTurn
END_Command

;;Attack Crab

Command Attack Crab
Present 315  - Crab
PrintMessage 93  - You are clumsy under water and the crab evades you
MinusScore 10
DoneWithTurn
END_Command

; Examine commands

;;Large Man

Command Examine Man
AtLocation 62  - Domain of Ra
PrintMessage 66  - You are not close enough, move north
DoneWithTurn
END_Command

;;Grotto

Command Examine Grotto
Present 249  - Grotto
Present 244  - Yellow Sphere
PrintMessage 92  - Description of Grotto with Sphere
DoneWithTurn
END_Command

;;Examine Red Sphere

Command Examine Sphere
Present 240  - Red Sphere
NounIsNumber 240  - Red Sphere
AtLocation 94  - Cave
PrintMessage 105  - Description of sphere on stalagmite
DoneWithTurn
END_Command

;;Examine Flat-topped Stalagmite

Command Examine Stalagmite
Present 240  - Red Sphere
NounIsNumber 251  - Flat-topped Stalagmite
AtLocation 94  - Cave
PrintMessage 104  - Description of stalagmite with sphere on it
DoneWithTurn
END_Command

;Examine Nouns in Ta

Command Examine Sphere
NounIsNumber 242  - Blue sphere
AtLocation 124  - Columns of Light
IsLocated 242 254  Sphere in columns of light
PrintMessage 118  - Description of sphere in light columns
DoneWithTurn
END_Command

Command Examine Columns
Present 254  - Light columns
NounIsNumber 254  - Light columns
IsLocated 242 254  - Sphere is in light columns
PrintMessage 117  - Description of light columns with sphere inside
DoneWithTurn
END_Command

; Cross Commands

Command Cross River
ReDirectTo Enter River
END_Command

; Swim Commands

Command Swim River
ReDirectTo Enter River
END_Command

; Help Commands

;;Elevating column

Command Help
AtLocation 44  - Half Sphere Chamber
IsCarrying 238  - White Sphere
IsCarrying 240  - Red Sphere
IsCarrying 242  - Blue Sphere
IsCarrying 244  - Yellow Sphere
PrintMessage 82  - Help: push circle
DoneWithTurn
END_Command

;;Help/Standing by west door/dark

Command Help
Present 201  - Flashlight
IsOFF 201  - Flashlight
AtLocation 49  Standing by west door (closed)
PrintMessage 106  - Turn on flashlight.  It should have been moved here.
END_Command

; Debug

Command Debug
ToggleFlag 0
DoneWithTurn
END_Command

